Posted: Thu Mar 10, 2011 11:35 am Post subject: Оптимизация селекта
Здравствуйте!
В коде программы обнаружился такой тормозящий запрос:
Code:
DATA : l_emptydate TYPE d.
DATA : BEGIN OF lt_bseg4paid OCCURS 0.
DATA : bukrs TYPE bseg-bukrs.
DATA : belnr TYPE bseg-belnr.
DATA : gjahr TYPE bseg-gjahr.
DATA : augdt TYPE bseg-augdt.
INCLUDE STRUCTURE gs_paid.
DATA : END OF lt_bseg4paid.
SELECT bukrs belnr gjahr augdt
ebeln ebelp pswsl pswbt
INTO TABLE lt_bseg4paid
FROM bseg
FOR ALL ENTRIES IN xtable
WHERE ebeln EQ xtable-ebeln
AND bukrs EQ ps_xtable-bukrs
AND koart EQ 'S'. "Account type = G/L Acounts!!!
CHECK sy-subrc EQ 0.
LOOP AT lt_bseg4paid.
IF lt_bseg4paid-augdt IS INITIAL.
SELECT SINGLE augdt
INTO lt_bseg4paid-augdt
FROM bseg
WHERE bukrs EQ lt_bseg4paid-bukrs AND
gjahr EQ lt_bseg4paid-gjahr AND
belnr EQ lt_bseg4paid-belnr AND
augdt NE l_emptydate.
ENDIF."lt_bseg4paid-augdt
CHECK NOT lt_bseg4paid-augdt IS INITIAL.
MOVE-CORRESPONDING lt_bseg4paid TO gs_paid.
COLLECT gs_paid INTO pt_paid.
ENDLOOP."lt_bseg4paid
С использованием каких таблиц можно обойти селект из bseg?
Age: 47 Joined: 14 Nov 2008 Posts: 300 Location: Russia
Posted: Thu Mar 10, 2011 6:14 pm Post subject:
Можно замерить и выбрать наиболее подходящий вариант:
1) По заказам на поставку найти фактуры из таблицы EKBE.
2) Выбрать соответствующие им документы из RBKP/RSEG уже по ключу.
3) Сформировать диапазон для BKPF-AWKEY = RBKP-BELNR+RBKP-GJAHR, ограничить выборку из BKPF ещё и по AWTYP = 'RMRP' (ну или как у вас) + RBKP-BUKRS.
4) Имея полные ключи BUKRS-BELNR-GJAHR FI-документов выбирать нужные вам данные либо с JOIN BSAS в п.3, либо отдельно из BSEG с FOR ALL ENTRIES по ключам, будет быстрее.
Скажите, а SELECT SINGLE внутри последующего цикла вам не тормозит работу?
P.S. Сам не измерял быстродействие предложенного варианта, возможно коллеги предложат что-то более эффективное. _________________ ABAP/4 You
Age: 48 Joined: 25 Jan 2008 Posts: 580 Location: Москва
Posted: Thu Mar 10, 2011 6:43 pm Post subject:
1.Согласен с Dmitriy, EKBE по входящим фактурам намного быстрее отработает.
2.По поводу AUGDT - это же дата выравнивания, а не дата оплаты.
Есть случаи, когда она не равна max(дата фактуры, дата оплаты), например когда выравниваются 2 фактуры с одной оплатой. _________________ С уважением,
Удав.
Age: 47 Joined: 14 Nov 2008 Posts: 300 Location: Russia
Posted: Thu Mar 10, 2011 7:45 pm Post subject:
Удав wrote:
2.По поводу AUGDT - это же дата выравнивания, а не дата оплаты. Есть случаи, когда она не равна max(дата фактуры, дата оплаты), например когда выравниваются 2 фактуры с одной оплатой.
Именно AUGDT как раз и смущает здесь. Я по таким случаям сразу же консультируюсь с FI-консультантами, т.к. оптимизацию теоретических случаев отношений M:N при оплате и выравнивании лучше разбирать отдельным пунктом. Должно быть возможным обойтись без SELECT SINGLE from BSEG в цикле, хоть и по ключу, но со знаком неравенства в условии WHERE. _________________ ABAP/4 You
Скажите, а SELECT SINGLE внутри последующего цикла вам не тормозит работу?
До него даже не дошло, не выходит из первого селекта при наличии в таблице FOR ALL ENTRUES 10 тыс. записей. Думаю, не будет тормозить, выборка почти по полному ключу.
Спасибо агроменное за подробный ответ! На следующей неделе выйдет консультант, будем с ним думать...
Dmitriy, сделал по вашему совету, скорость норимальная. Спасибо еще раз!
Code:
DATA : BEGIN OF lt_bseg4paid OCCURS 0.
DATA : bukrs TYPE bseg-bukrs.
DATA : belnr TYPE bseg-belnr.
DATA : gjahr TYPE bseg-gjahr.
DATA : buzei TYPE bseg-buzei.
DATA : augdt TYPE bseg-augdt.
INCLUDE STRUCTURE gs_paid.
DATA : END OF lt_bseg4paid.
DATA: BEGIN OF lt_ekbe OCCURS 0,
ebeln TYPE ekbe-ebeln,
ebelp TYPE ekbe-ebelp,
gjahr TYPE ekbe-gjahr,
zekkn TYPE ekbe-zekkn,
vgabe TYPE ekbe-vgabe,
belnr TYPE ekbe-belnr,
buzei TYPE ekbe-buzei,
END OF lt_ekbe.
DATA: BEGIN OF lt_bkpf OCCURS 0,
bukrs TYPE bkpf-bukrs,
belnr TYPE bkpf-belnr,
gjahr TYPE bkpf-gjahr,
END OF lt_bkpf.
DATA: BEGIN OF ls_awkey,
belnr TYPE bkpf-belnr,
gjahr TYPE bkpf-gjahr,
END OF ls_awkey.
IF NOT xtable[] IS INITIAL.
SELECT ebeln
ebelp
gjahr
zekkn
vgabe
belnr
buzei
INTO TABLE lt_ekbe
FROM ekbe
FOR ALL ENTRIES IN xtable
WHERE ebeln = xtable-ebeln.
ENDIF.
LOOP AT lt_ekbe.
ls_awkey-belnr = lt_ekbe-belnr.
ls_awkey-gjahr = lt_ekbe-gjahr.
SELECT bukrs
belnr
gjahr
APPENDING TABLE lt_bkpf
FROM bkpf
WHERE bukrs IN so_bukrs
AND awtyp = 'RMRP'
AND awkey = ls_awkey.
ENDLOOP.
SORT lt_bkpf.
DELETE ADJACENT DUPLICATES FROM lt_bkpf.
IF NOT lt_bkpf[] IS INITIAL.
SELECT bukrs belnr gjahr buzei
augdt
ebeln ebelp pswsl pswbt
INTO TABLE lt_bseg4paid
FROM bseg
FOR ALL ENTRIES IN lt_bkpf
WHERE bukrs EQ lt_bkpf-bukrs
AND belnr EQ lt_bkpf-belnr
AND gjahr EQ lt_bkpf-gjahr
AND koart EQ 'S'. "Account type = G/L Acounts!!!
ENDIF.
Age: 47 Joined: 14 Nov 2008 Posts: 300 Location: Russia
Posted: Wed Mar 16, 2011 3:13 pm Post subject:
Попробуйте ещё измерить, будет ли быстрее ч/з FOR ALL ENTRIES таблицы ключей AWKEY без выборки в цикле и без последующего DELETE дубликатов. Таблицу lt_awkey сделайте из одного только поля AWKEY. Возможно получите ускорение работы вот этого кусочка кода:
Code:
LOOP AT lt_ekbe.
ls_awkey-belnr = lt_ekbe-belnr.
ls_awkey-gjahr = lt_ekbe-gjahr.
SELECT bukrs
belnr
gjahr
APPENDING TABLE lt_bkpf
FROM bkpf
WHERE bukrs IN so_bukrs
AND awtyp = 'RMRP'
AND awkey = ls_awkey.
ENDLOOP.
SORT lt_bkpf.
DELETE ADJACENT DUPLICATES FROM lt_bkpf.
Попробуйте ещё измерить, будет ли быстрее ч/з FOR ALL ENTRIES таблицы ключей AWKEY без выборки в цикле и без последующего DELETE дубликатов. Таблицу lt_awkey сделайте из одного только поля AWKEY.
Хорошая идея, выделенный вами фрагмент стал быстрее раз в 5
Насчет дупликатов, разве в bkpf не может быть дупликатов по AWKEY?
Code:
DATA : l_emptydate TYPE d.
DATA : BEGIN OF lt_bseg4paid OCCURS 0.
DATA : bukrs TYPE bseg-bukrs.
DATA : belnr TYPE bseg-belnr.
DATA : gjahr TYPE bseg-gjahr.
DATA : buzei TYPE bseg-buzei.
DATA : augdt TYPE bseg-augdt.
INCLUDE STRUCTURE gs_paid.
DATA : END OF lt_bseg4paid.
DATA: BEGIN OF lt_ekbe OCCURS 0,
ebeln TYPE ekbe-ebeln,
ebelp TYPE ekbe-ebelp,
gjahr TYPE ekbe-gjahr,
zekkn TYPE ekbe-zekkn,
vgabe TYPE ekbe-vgabe,
belnr TYPE ekbe-belnr,
buzei TYPE ekbe-buzei,
END OF lt_ekbe.
DATA: BEGIN OF lt_bkpf OCCURS 0,
bukrs TYPE bkpf-bukrs,
belnr TYPE bkpf-belnr,
gjahr TYPE bkpf-gjahr,
END OF lt_bkpf.
DATA: BEGIN OF ls_awkey,
belnr TYPE bkpf-belnr,
gjahr TYPE bkpf-gjahr,
END OF ls_awkey.
DATA: BEGIN OF lt_awkey OCCURS 0,
awkey TYPE bkpf-awkey,
END OF lt_awkey.
IF NOT xtable[] IS INITIAL.
SELECT ebeln
ebelp
gjahr
zekkn
vgabe
belnr
buzei
INTO TABLE lt_ekbe
FROM ekbe
FOR ALL ENTRIES IN xtable
WHERE ebeln = xtable-ebeln.
ENDIF.
IF NOT lt_awkey[] IS INITIAL.
SELECT bukrs
belnr
gjahr
INTO TABLE lt_bkpf
FROM bkpf
FOR ALL ENTRIES IN lt_awkey
WHERE bukrs IN so_bukrs
AND awtyp = 'RMRP'
AND awkey = lt_awkey-awkey.
ENDIF.
SORT lt_bkpf.
DELETE ADJACENT DUPLICATES FROM lt_bkpf.
IF NOT lt_bkpf[] IS INITIAL.
SELECT bukrs belnr gjahr buzei
augdt
ebeln ebelp pswsl pswbt
INTO TABLE lt_bseg4paid
FROM bseg
FOR ALL ENTRIES IN lt_bkpf
WHERE bukrs EQ lt_bkpf-bukrs
AND belnr EQ lt_bkpf-belnr
AND gjahr EQ lt_bkpf-gjahr
AND koart EQ 'S'. "Account type = G/L Acounts!!!
ENDIF.
Age: 47 Joined: 14 Nov 2008 Posts: 300 Location: Russia
Posted: Wed Mar 16, 2011 4:18 pm Post subject:
Лазарев wrote:
Насчет дупликатов, разве в bkpf не может быть дупликатов по AWKEY?
У вас есть ключ одной закупочной фактуры логистики (RBKP-BELNR, RBKP-GJAHR), по которому вы находите одну же фактуру FI. Возможно система и позволяет сделать несколько FI-фактур к одной логистической закупочной, лучше уточните у консультантов. _________________ ABAP/4 You
You cannot post new topics in this forum You cannot reply to topics in this forum You cannot edit your posts in this forum You cannot delete your posts in this forum You cannot vote in polls in this forum You cannot attach files in this forum You can download files in this forum
All product names are trademarks of their respective companies. SAPNET.RU websites are in no way affiliated with SAP AG. SAP, SAP R/3, R/3 software, mySAP, ABAP, BAPI, xApps, SAP NetWeaver and any other are registered trademarks of SAP AG. Every effort is made to ensure content integrity. Use information on this site at your own risk.
