SAP R/3 форум ABAP консультантов
Russian ABAP Developer's Club

Home - FAQ - Search - Memberlist - Usergroups - Profile - Log in to check your private messages - Register - Log in - English
Blogs - Weblogs News

Conditions в me23n



 
Post new topic   Reply to topic    Russian ABAP Developer's Club Forum Index -> ABAP
View previous topic :: View next topic  
Author Message
Влад
Специалист
Специалист



Joined: 26 Dec 2007
Posts: 63
PostPosted: Tue Feb 17, 2009 6:27 pm    Post subject: Conditions в me23n Reply with quote
Коллеги, приходилось ли кому-нибудь расcчитывать Condition Net Value. Какой ФМ использовать?

condition_me23n.PNG
 Description:
 Filesize:  16.67 KB
 Viewed:  7926 Time(s)

condition_me23n.PNG
Back to top
View user's profile Send private message
ghost
Специалист
Специалист


Age: 37
Joined: 18 Jan 2008
Posts: 71
Location: Tashkent-Astana-Moscow
PostPosted: Tue Feb 17, 2009 9:26 pm    Post subject: Reply with quote
расчет зависит от схемы калькуляции Smile настройкой ее чаще всего занимается консультант. А зачем вам расчитывать заново это значение ?
_________________
Пользователь не знает, чего он хочет, пока не увидит то, что он получил. (Э. Йодан)
Back to top
View user's profile Send private message Send e-mail Blog
vga
Мастер
Мастер


Age: 170
Joined: 04 Oct 2007
Posts: 1218
Location: Санкт-Петербург
PostPosted: Wed Feb 18, 2009 10:29 am    Post subject: Reply with quote
Может Вам как-то поможет программа расчета прайсинга от Сергея Королева?

Code:
REPORT z_test_po_cond .

PARAMETERS:
  p_ebeln TYPE ekko-ebeln OBLIGATORY.

DATA:
  ls_komk    TYPE komk,
  ls_komp    TYPE komp,

  lt_komv    TYPE TABLE OF komv,

  ls_t001    TYPE t001,
  ls_t001w   TYPE t001w,
  ls_ekko    TYPE ekko,
  lt_ekpo    TYPE TABLE OF ekpo.

FIELD-SYMBOLS:
  <fs_ekpo> TYPE ekpo.

START-OF-SELECTION.
  CALL FUNCTION 'ME_EKKO_SINGLE_READ'
       EXPORTING
            pi_ebeln         = p_ebeln
       IMPORTING
            po_ekko          = ls_ekko
       EXCEPTIONS
            no_records_found = 1
            OTHERS           = 2.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  CALL FUNCTION 'ME_EKPO_READ_WITH_EBELN'
       EXPORTING
            pi_ebeln             = p_ebeln
       TABLES
            pto_ekpo             = lt_ekpo
       EXCEPTIONS
            err_no_records_found = 1
            OTHERS               = 2.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.


  CALL FUNCTION 'K_READ_T001'
       EXPORTING
            i_bukrs   = ls_ekko-bukrs
       IMPORTING
            e_t001    = ls_t001
       EXCEPTIONS
            not_found = 1
            OTHERS    = 2.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.


  LOOP AT lt_ekpo ASSIGNING <fs_ekpo>.

*--{ VGA ECDKxxxxxx:insert
    CALL FUNCTION 'MM_REFRESH_PARTNERS'. "memory free
*--} VGA ECDKxxxxxx:end

    CALL FUNCTION 'ME_FILL_KOMK_PO'
         EXPORTING
              i_ekko = ls_ekko
              i_ekpo = <fs_ekpo>
              i_t001 = ls_t001
         IMPORTING
              e_komk = ls_komk.

    CALL FUNCTION 'T001W_SINGLE_READ'
         EXPORTING
              t001w_werks = <fs_ekpo>-werks
         IMPORTING
              wt001w      = ls_t001w
         EXCEPTIONS
              not_found   = 1
              OTHERS      = 2.

    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.

    CALL FUNCTION 'ME_FILL_KOMP_PO'
         EXPORTING
              i_ekpo  = <fs_ekpo>
              i_t001w = ls_t001w
              i_ekko  = ls_ekko
              i_komk  = ls_komk
         IMPORTING
              e_komp  = ls_komp.

    CALL FUNCTION 'PRICING'
         EXPORTING
              comm_head_i = ls_komk
              comm_item_i = ls_komp
         TABLES
              tkomv       = lt_komv.

  ENDLOOP.
Back to top
View user's profile Send private message Blog Visit poster's website
Display posts from previous:   
Post new topic   Reply to topic    Russian ABAP Developer's Club Forum Index -> ABAP All times are GMT + 4 Hours
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum


All product names are trademarks of their respective companies. SAPNET.RU websites are in no way affiliated with SAP AG.
SAP, SAP R/3, R/3 software, mySAP, ABAP, BAPI, xApps, SAP NetWeaver and any other are registered trademarks of SAP AG.
Every effort is made to ensure content integrity. Use information on this site at your own risk.