SAP R/3 форум ABAP консультантов
Russian ABAP Developer's Club

Home - FAQ - Search - Memberlist - Usergroups - Profile - Log in to check your private messages - Register - Log in - English
Blogs - Weblogs News

BAPI_SALESORDER_CHANGE



 
Post new topic   Reply to topic    Russian ABAP Developer's Club Forum Index -> SD
View previous topic :: View next topic  
Author Message
admin
Администратор
Администратор



Joined: 01 Sep 2007
Posts: 1639

PostPosted: Thu Sep 20, 2007 11:04 am    Post subject: BAPI_SALESORDER_CHANGE Reply with quote

BAPI_SALESORDER_CHANGE - Sales order: Change Sales Order

Functionality
You can use this method to change or delete sales orders.
You can change header, item, schedule line and configuration data.
In general, note that you should:
- Only specify fields that should be changed
- Select these fields by entering an X in the checkboxes
- Enter a U in the UPDATEFLAG field
- Always specify key fields when changing the data, including in the checkboxes
- The configuration is an exception here. If this needs to be changed, you need to complete it again fully.
- Maintain quantities and dates in the schedule line data
- Possible UPDATEFLAGS:
U = change
D = delete
I = add

Code:
*&---------------------------------------------------------------------*
*&      Form  rechazar
*&---------------------------------------------------------------------*
FORM rechazar .
 DATA: i_hdr  TYPE bapisdh1,
       i_hdrx TYPE bapisdh1x,
       i_ret  TYPE bapiret2 OCCURS 0 WITH HEADER LINE,
       i_itm  TYPE bapisditm OCCURS 0 WITH HEADER LINE,
       i_itmx TYPE bapisditmx  OCCURS 0 WITH HEADER LINE.

 REFRESH: i_itm, i_itmx, i_ret.
 CLEAR: i_hdr, i_hdrx.
 i_hdr-sd_doc_cat  = 'C'.
 i_hdrx-updateflag = 'U'.

 SELECT * FROM vbap
  WHERE vbeln = i_listado-vbeln.

   i_itm-itm_number = vbap-posnr.
   i_itm-reason_rej = 'Z1'.

   i_itmx-updateflag = 'U'.
   i_itmx-itm_number = vbap-posnr.
   i_itmx-reason_rej = 'X'.

   APPEND i_itm.
   APPEND i_itmx.
 ENDSELECT.

 CALL FUNCTION 'BAPI_SALESORDER_CHANGE'
   EXPORTING
     salesdocument     = i_listado-vbeln
     order_header_in   = i_hdr
     order_header_inx  = i_hdrx
     behave_when_error = 'P'
   TABLES
     return            = i_ret
     order_item_in     = i_itm
     order_item_inx    = i_itmx.

ENDFORM.                    " rechazar


Code:
REPORT ZEGGY_ORDER_CHANGE_TEST MESSAGE-ID 38.

*----------------------------------------------------------------------*
* Selection Screen Definitions                                         *
*----------------------------------------------------------------------*
PARAMETERS: P_VBELN  TYPE VBAP-VBELN OBLIGATORY,   "Order Number
            P_POSNR  TYPE VBAP-POSNR OBLIGATORY,   "Order Item
             P_ETENR  TYPE VBEP-ETENR,              "Schedule Line
           P_ITMQTY TYPE BAPISDITM-TARGET_QTY,    "Order Quantity
           P_REQQTY TYPE BAPISCHDL-REQ_QTY.       "Schedule Line Qty

SELECTION-SCREEN: SKIP.

PARAMETERS: R_SCHD RADIOBUTTON GROUP RAD,  "Change Schedule Line Qty
           R_ITEM RADIOBUTTON GROUP RAD,  "Change Order Item Qty
           R_BOTH RADIOBUTTON GROUP RAD.  "Change Both Qtys

*----------------------------------------------------------------------*
* Internal Tables/Structures/Variables for calling BAPI.               *
*----------------------------------------------------------------------*
DATA: I_HDR  TYPE BAPISDH1,
     I_HDRX TYPE BAPISDH1X,
     I_RET  TYPE BAPIRET2 OCCURS 0 WITH HEADER LINE.

DATA: BEGIN OF I_ITM OCCURS 10.
           INCLUDE STRUCTURE BAPISDITM.
DATA: END OF I_ITM.

DATA: BEGIN OF I_ITMX OCCURS 10.
           INCLUDE STRUCTURE BAPISDITMX.
DATA: END OF I_ITMX.

DATA: BEGIN OF I_SCHED OCCURS 10.
           INCLUDE STRUCTURE BAPISCHDL.
DATA: END OF I_SCHED.

DATA: BEGIN OF I_SCHEDX OCCURS 10.
           INCLUDE STRUCTURE BAPISCHDLX.
DATA: END OF I_SCHEDX.

*----------------------------------------------------------------------*
* START-OF-SELECTION Event                                             *
*----------------------------------------------------------------------*
START-OF-SELECTION.

    "---------------------------------------------------
    " Validate require selection screen criteria.
    "---------------------------------------------------
    IF R_BOTH = 'X'.
       IF P_ETENR  IS INITIAL OR
          P_REQQTY IS INITIAL.
          MESSAGE E000
             WITH 'Enter a Schedule Line Number and Qty.'.
       ENDIF.
       IF P_ITMQTY IS INITIAL.
          MESSAGE E000
             WITH 'Enter an Order Item Quantity.'.
       ENDIF.

    ELSEIF R_SCHD = 'X'.
           IF P_ETENR  IS INITIAL OR
              P_REQQTY IS INITIAL.
              MESSAGE E000
                 WITH 'Enter a Schedule Line Number and Qty.'.
           ENDIF.
    ELSE.
       IF P_ITMQTY IS INITIAL.
          MESSAGE E000
             WITH 'Enter an Order Item Quantity.'.
       ENDIF.
    ENDIF.

    "----------------------------------------------
    " Initialize internal tables.
    "----------------------------------------------
    REFRESH: I_ITM, I_ITMX, I_SCHED, I_SCHEDX, I_RET.
    CLEAR:   I_ITM, I_ITMX, I_SCHED, I_SCHEDX, I_RET.

    "----------------------------------------------
    " Fill required ORDER_HEADER_IN data.
    "----------------------------------------------
    I_HDR-SD_DOC_CAT  = 'C'.
    I_HDRX-UPDATEFLAG = 'U'.

    "----------------------------------------------
    " Fill required ORDER_ITEM_IN data.
    "----------------------------------------------
    IF R_ITEM = 'X' OR R_BOTH = 'X'.

       I_ITM-ITM_NUMBER = P_POSNR.
       I_ITM-TARGET_QTY = P_ITMQTY.

       I_ITMX-UPDATEFLAG = 'U'.
       I_ITMX-ITM_NUMBER = P_POSNR.
       I_ITMX-TARGET_QTY = 'X'.

       APPEND I_ITM.
       APPEND I_ITMX.
    ENDIF.

    "----------------------------------------------
    " Fill required SCHEDULE_LINES data.
    "----------------------------------------------
    IF R_SCHD = 'X' OR R_BOTH = 'X'.

       I_SCHED-ITM_NUMBER = P_POSNR.
       I_SCHED-SCHED_LINE = P_ETENR.
       I_SCHED-REQ_QTY    = P_REQQTY.

       I_SCHEDX-UPDATEFLAG = 'U'.
       I_SCHEDX-ITM_NUMBER = P_POSNR.
       I_SCHEDX-SCHED_LINE = P_ETENR.
       I_SCHEDX-REQ_QTY    = 'X'.

       APPEND I_SCHED.
       APPEND I_SCHEDX.
    ENDIF.

    CALL FUNCTION 'BAPI_SALESORDER_CHANGE'
         EXPORTING
                  SALESDOCUMENT     = P_VBELN
                  ORDER_HEADER_IN   = I_HDR
                  ORDER_HEADER_INX  = I_HDRX
                  BEHAVE_WHEN_ERROR = 'P'
         TABLES
                  RETURN            = I_RET
                  ORDER_ITEM_IN     = I_ITM
                  ORDER_ITEM_INX    = I_ITMX
                  SCHEDULE_LINES    = I_SCHED
                  SCHEDULE_LINESX   = I_SCHEDX.

    CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'.

*end of program ZEGGY_ORDER_CHANGE_TEST.
Back to top
View user's profile Send private message
admin
Администратор
Администратор



Joined: 01 Sep 2007
Posts: 1639

PostPosted: Wed Jul 01, 2009 4:35 pm    Post subject: Reply with quote

Author: east

Code:
FUNCTION Z_SALESORDER_CHANGE.
*"----------------------------------------------------------------------
*"*"Локальный интерфейс:
*"  IMPORTING
*"     VALUE(I_VBELN) LIKE  BAPIVBELN-VBELN OPTIONAL
*"     VALUE(I_UPDATEFLAG) TYPE  UPDKZ_D OPTIONAL
*"  TABLES
*"      POSITIONS STRUCTURE  ZSALESORDER_CREATE_POS
*"      RETURN STRUCTURE  BAPIRET2
*"----------------------------------------------------------------------
DATA: header  like BAPISDH1X.
DATA: item    like BAPISDITM  OCCURS 0 WITH HEADER LINE.
DATA: itemx   like BAPISDITMX OCCURS 0 WITH HEADER LINE.
DATA: schdl   like BAPISCHDL  OCCURS 0 WITH HEADER LINE.
DATA: schdlx  like BAPISCHDLX OCCURS 0 WITH HEADER LINE.
DATA: wa_makt type makt.
DATA: salesdocument like BAPIVBELN-VBELN.
header-updateflag = i_updateflag.

CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
  EXPORTING
    INPUT  = i_vbeln
  IMPORTING
    OUTPUT = salesdocument.

IF i_updateflag <> 'D'.
  LOOP AT positions.
    item-itm_number  = itemx-itm_number = positions-itm_number.
    itemx-updateflag = positions-updateflag.
    CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
      EXPORTING
        INPUT  = positions-material
      IMPORTING
        OUTPUT = item-material.

      itemx-material   = 'X'.

    SELECT SINGLE * FROM makt INTO wa_makt WHERE matnr EQ item-material.
      IF sy-subrc EQ 0.
        item-target_qty = positions-target_qty.
        itemx-target_qty = 'X'.
        item-short_text = wa_makt-maktx.
        itemx-short_text = 'X'.
        item-purch_date = sy-datum.
        itemx-purch_date = 'X'.
        PERFORM correct_schdl TABLES schdl
                                     schdlx
                               USING salesdocument
                                     item-itm_number
                                     item-target_qty.
        APPEND item.
        APPEND itemx.
        APPEND schdl.
        APPEND schdlx.
      ENDIF.
  ENDLOOP.
ENDIF.

CALL FUNCTION 'BAPI_SALESORDER_CHANGE'
  EXPORTING
    SALESDOCUMENT               = salesdocument
    ORDER_HEADER_INX            = header
    BEHAVE_WHEN_ERROR           = space
  TABLES
    RETURN                      = return
    ORDER_ITEM_IN               = item
    ORDER_ITEM_INX              = itemx
    SCHEDULE_LINES              = schdl
    SCHEDULE_LINESX             = schdlx.

CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
   WAIT          = 'X'
IMPORTING
   RETURN        = return.

ENDFUNCTION.
*&-------------------------------------------------------------------
*&-- FORM CORRECT SCHEDULE
*&-------------------------------------------------------------------
FORM correct_schdl TABLES lt_schdl   STRUCTURE bapischdl
                          lt_schdlx  STRUCTURE bapischdlx
                    USING l_vbeln
                          l_posnr
                          l_tar_qty.

DATA: BEGIN OF lt_sh OCCURS 0.
DATA: ETENR LIKE vbep-etenr.
DATA: WMENG LIKE vbep-wmeng.
DATA: END OF lt_sh.

  SELECT SINGLE etenr WMENG INTO lt_sh FROM vbep WHERE vbeln eq l_vbeln
                                                   AND posnr eq l_posnr.
    IF sy-subrc eq 0.
      lt_schdl-itm_number = lt_schdlx-itm_number = l_posnr.
      lt_schdl-sched_line = lt_schdlx-sched_line = lt_sh-etenr.
      lt_schdl-req_qty = l_tar_qty.
      lt_schdlx-req_qty = 'X'.
      lt_schdlx-updateflag = 'U'.
    ENDIF.
ENDFORM.
Back to top
View user's profile Send private message
admin
Администратор
Администратор



Joined: 01 Sep 2007
Posts: 1639

PostPosted: Wed Jul 01, 2009 4:41 pm    Post subject: Reply with quote

Example filling SCHEDULE lines by kizif

Code:
DATA:  lt_schdl  TYPE TABLE OF bapischdl WITH HEADER LINE,
           lt_schdlx TYPE TABLE OF bapischdlx  WITH HEADER LINE.
DATA:  l_vbeln TYPE vbep-vbeln.

DATA: BEGIN OF lt_sh OCCURS 0,
         posnr LIKE vbep-posnr,
         etenr LIKE vbep-etenr,
       END OF lt_sh.

  SELECT * INTO CORRESPONDING FIELDS OF TABLE lt_sh
    FROM vbep WHERE vbeln = l_vbeln.

  CHECK sy-subrc IS INITIAL.

  LOOP AT lt_sh FROM 2.
    lt_schdlx-updateflag = 'D'.
    lt_schdl-itm_number = lt_shadx-itm_number = lt_sh-posnr.
    lt_schdl-sched_line = lt_shadx-sched_line = lt_sh-etenr.
    lt_schdl-req_qty = 0.
    lt_schdlx-req_qty = 'X'.
    APPEND lt_schdlx.
    APPEND lt_schdl.
  ENDLOOP.
  READ TABLE lt_schdlx INDEX 1.
  lt_schdlx-sched_line = 1.
  lt_schdlx-updateflag = 'U'.
  MODIFY lt_schdlx INDEX 1.
  REFRESH lt_sh.CLEAR lt_sh.
Back to top
View user's profile Send private message
admin
Администратор
Администратор



Joined: 01 Sep 2007
Posts: 1639

PostPosted: Wed Jul 01, 2009 4:45 pm    Post subject: Reply with quote

Code:
Example: Source code for function module Z_IDOC_INPUT_GOODSENTRY

FUNCTION z_idoc_input_goodsentry .
*"----------------------------------------------------------------------
*"*"Global interface:
*"  IMPORTING
*"     VALUE(INPUT_METHOD) LIKE  BDWFAP_PAR-INPUTMETHD
*"     VALUE(MASS_PROCESSING) LIKE  BDWFAP_PAR-MASS_PROC
*"  EXPORTING
*"     VALUE(WORKFLOW_RESULT) LIKE  BDWF_PARAM-RESULT
*"     VALUE(APPLICATION_VARIABLE) LIKE  BDWF_PARAM-APPL_VAR
*"     VALUE(IN_UPDATE_TASK) LIKE  BDWFAP_PAR-UPDATETASK
*"     VALUE(CALL_TRANSACTION_DONE) LIKE  BDWFAP_PAR-CALLTRANS
*"  TABLES
*"      IDOC_CONTRL STRUCTURE  EDIDC
*"      IDOC_DATA STRUCTURE  EDIDD
*"      IDOC_STATUS STRUCTURE  BDIDOCSTAT
*"      RETURN_VARIABLES STRUCTURE  BDWFRETVAR
*"      SERIALIZATION_INFO STRUCTURE  BDI_SER
*"  EXCEPTIONS
*"      WF_ERROR_PROCESS
*"----------------------------------------------------------------------
  TABLES: ekko, ekpo, eban, ekkn, vbap, vbak, vbep.
  DATA: xe1edp09 TYPE STANDARD TABLE OF e1edp09 WITH HEADER LINE.
  DATA: goodsmvt_header LIKE bapi2017_gm_head_01.
  DATA: goodsmvt_item TYPE STANDARD TABLE OF bapi2017_gm_item_create
                                            WITH HEADER LINE.
  DATA: return TYPE STANDARD TABLE OF bapiret2 WITH HEADER LINE.
* for the BAPI_SALESORDER_CHANGE --------------------------------------
  DATA: order_header_in  LIKE bapisdh1.
  DATA: order_header_inx LIKE bapisdh1x.
  DATA: schedule_lines
          TYPE STANDARD TABLE OF bapischdl WITH HEADER LINE.
  DATA: schedule_linesx
          TYPE STANDARD TABLE OF bapischdlx WITH HEADER LINE.

  TABLES: bapi2017_gm_head_ret.  " IDoc: Document header date segment
  CLEAR workflow_result.

*- Prfen, da alle IDOCs den richtigen Basis IDoc Typ haben ----------*
  LOOP AT idoc_contrl.
    IF idoc_contrl-idoctp(6) <> 'DESADV'.
      MESSAGE ID 'E0' TYPE 'E' NUMBER '029'
      WITH idoc_contrl-idoctp ' ' 'IDOC_INPUT_DESADV'
      RAISING wf_error_process.
    ENDIF.
  ENDLOOP.
*- kein Zwischenbeleg gefunden ----------------------------------------*
  IF idoc_contrl-docnum EQ space.
    MESSAGE e770(e0) RAISING wf_error_process.
  ENDIF.
*- Feststellen IDOC-Nummer - Weiterverarbeitung starten ---------------*
  LOOP AT idoc_contrl.
    REFRESH xe1edp09.
    LOOP AT idoc_data WHERE docnum EQ idoc_contrl-docnum.
      CASE idoc_data-segnam.
        WHEN 'E1EDP09'. APPEND idoc_data-sdata TO xe1edp09.
      ENDCASE.
*- Daten aus interner Tabelle in entsprechenden Strukturen merken -----*
    ENDLOOP.
  ENDLOOP.
  CLEAR goodsmvt_header.
  goodsmvt_header-pstng_date = sy-datum.
  goodsmvt_header-doc_date   = sy-datum.
  LOOP AT xe1edp09.
    ekpo-ebeln = xe1edp09-vbeln.
    ekpo-ebelp = xe1edp09-posnr.

    CLEAR idoc_status.
    idoc_status-msgty  = 'I'.
    idoc_status-status  = '62'.
    idoc_status-msgid  = '38'.
    idoc_status-msgno  = '000'.
    SELECT * FROM ekpo WHERE ebeln EQ ekpo-ebeln
                         AND ebelp EQ ekpo-ebelp.
      idoc_status-msgv1  = '... Purchase order found:'.
      idoc_status-msgv2  = ekpo-ebeln.
      idoc_status-msgv3  = ekpo-ebelp.
      APPEND idoc_status.
      SELECT * FROM ekko WHERE ebeln EQ ekpo-ebeln.

        SELECT * FROM ekkn WHERE ebeln EQ ekpo-ebeln
                             AND ebelp EQ ekpo-ebelp.
          SELECT * FROM vbap WHERE vbeln EQ ekkn-vbeln
                               AND posnr EQ ekkn-vbelp.
            idoc_status-msgv1  = '... Sales order found:'.
            idoc_status-msgv2  = vbap-vbeln.
            idoc_status-msgv3  = vbap-posnr.
            APPEND idoc_status.
            ekpo-menge = xe1edp09-lfimg.
            goodsmvt_header-ref_doc_no = 'Redboats'.
            goodsmvt_item-material   = vbap-matnr.
            goodsmvt_item-plant      = vbap-werks.
            IF vbap-lgort IS INITIAL.
              SELECT lgort INTO vbap-lgort UP TO 1 ROWS FROM t001l
                WHERE werks EQ vbap-werks.
              ENDSELECT.
            ENDIF.
            goodsmvt_item-stge_loc   = vbap-lgort.
            goodsmvt_item-move_type  = '101'.
            goodsmvt_item-vendor     = ekko-lifnr.
            goodsmvt_item-entry_qnt  = ekpo-menge.
            goodsmvt_item-entry_uom  = 'EA'.
            goodsmvt_item-po_number  = ekpo-ebeln.
            goodsmvt_item-po_item    = ekpo-ebelp.
            goodsmvt_item-mvt_ind = 'B'.
            APPEND goodsmvt_item.
          ENDSELECT.
        ENDSELECT.
      ENDSELECT.
    ENDSELECT.
  ENDLOOP.
*--- Post if there is something to post -------------------------------
  REFRESH return.

  CLEAR bapi2017_gm_head_ret.
  IF NOT goodsmvt_item[] IS INITIAL.
    CALL FUNCTION 'BAPI_GOODSMVT_CREATE'
*      DESTINATION 'NONE'
      EXPORTING
        goodsmvt_header             = goodsmvt_header
        goodsmvt_code               = '01'
      IMPORTING
        materialdocument            = bapi2017_gm_head_ret-mat_doc
        matdocumentyear             = bapi2017_gm_head_ret-doc_year
      TABLES
        goodsmvt_item               = goodsmvt_item
        return                      = return.
  ENDIF.
  COMMIT WORK AND WAIT.
*  break axel.
*-------------------------------------------------------------
  idoc_status-docnum = idoc_contrl-docnum.
  idoc_status-status = '62'.
  LOOP AT return.
    idoc_status-msgty  = return-type.
    idoc_status-msgid  = return-id.
    idoc_status-msgno  = return-number.
    idoc_status-msgv1  = return-message_v1.
    idoc_status-msgv2  = return-message_v2.
    idoc_status-msgv3  = return-message_v3.
    idoc_status-msgv4  = return-message_v4.
    APPEND idoc_status.
  ENDLOOP.
*-------------------------------------------------------------
  IF NOT bapi2017_gm_head_ret-mat_doc IS INITIAL
  AND NOT vbap-vbeln IS INITIAL.
    CLEAR order_header_in.
    CLEAR order_header_inx.
    order_header_in-dlv_block = space.
    order_header_inx-dlv_block = 'X'.
    order_header_inx-updateflag = 'U'.
*-- update schedule lines so that delivery can be created immediately
    REFRESH: schedule_lines, schedule_linesx.
    SELECT * FROM vbep WHERE posnr EQ vbap-posnr
                         AND vbeln EQ vbap-vbeln.
      schedule_lines-itm_number = vbep-posnr.
      schedule_lines-sched_line = vbep-etenr.
      schedule_lines-tp_date = sy-datum.
      schedule_lines-ms_date = sy-datum.
      schedule_linesx-updateflag = 'U'.
      schedule_linesx-itm_number = schedule_lines-itm_number.
      schedule_linesx-sched_line = schedule_lines-sched_line.

      schedule_linesx-tp_date = 'X'.
      schedule_linesx-ms_date = 'X'.
      APPEND schedule_lines.
      APPEND schedule_linesx.
    ENDSELECT.
    CALL FUNCTION 'BAPI_SALESORDER_CHANGE'
*         DESTINATION 'NONE'
         EXPORTING
              salesdocument    = vbap-vbeln
              order_header_in  = order_header_in
              order_header_inx = order_header_inx
         TABLES
              schedule_lines   = schedule_lines
              schedule_linesx  = schedule_linesx
              return           = return.

    COMMIT WORK AND WAIT.
*-------------------------------------------------------------
    REFRESH return.
    LOOP AT return.
      idoc_status-msgty  = return-type.
      idoc_status-msgid  = return-id.
      idoc_status-msgno  = return-number.
      idoc_status-msgv1  = return-message_v1.
      idoc_status-msgv2  = return-message_v2.
      idoc_status-msgv3  = return-message_v3.
      idoc_status-msgv4  = return-message_v4.
      APPEND idoc_status.
    ENDLOOP.
  ENDIF.
*-------------------------------------------------------------
  IF NOT bapi2017_gm_head_ret-mat_doc IS INITIAL.
    IF return[] IS INITIAL.
      idoc_status-status = '53'.
    ELSE.
      idoc_status-status = '52'.
    ENDIF.
    idoc_status-msgty  = 'S'.
    idoc_status-msgid  = 'M7'.
    idoc_status-msgno  = '060'.
    idoc_status-msgv1  = bapi2017_gm_head_ret-mat_doc.
    idoc_status-msgv2  = bapi2017_gm_head_ret-doc_year.
    APPEND idoc_status.
  ELSE.
    idoc_status-status = '51'.
    idoc_status-msgty  = 'E'.

    idoc_status-msgid  = '38'.
    idoc_status-msgno  = '000'.
    idoc_status-msgv1 = 'Goods entry posting failed for purchase doc:'.
    idoc_status-msgv2  = ekpo-ebeln.
    idoc_status-msgv3  = ekpo-ebelp.
    APPEND idoc_status.
  ENDIF.
  LOOP AT idoc_status.
    idoc_status-docnum = idoc_contrl-docnum.
    MODIFY idoc_status.
  ENDLOOP.
ENDFUNCTION.
Back to top
View user's profile Send private message
Display posts from previous:   
Post new topic   Reply to topic    Russian ABAP Developer's Club Forum Index -> SD All times are GMT + 4 Hours
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You cannot download files in this forum


All product names are trademarks of their respective companies. SAPNET.RU websites are in no way affiliated with SAP AG.
SAP, SAP R/3, R/3 software, mySAP, ABAP, BAPI, xApps, SAP NetWeaver and any other are registered trademarks of SAP AG.
Every effort is made to ensure content integrity. Use information on this site at your own risk.